{Esta rotina imprime o caracter em AL e avanca o cursor}
procedure imprime_char; assembler;
asm
  push  ax
  push  bx
  mov   ah,$0E
  mov   bx,0
  int   $10
  pop   bx
  pop   ax
end;

procedure salta_linha; assembler;
asm
  push  ax
  mov   al,10
  call  imprime_char
  mov   al,13
  call  imprime_char
  pop   ax
end;


{A rotina a seguir imprime uma null-terminated string,
 cujo endereco esta em SI}
procedure imprime_nts;assembler;
asm
  push  ax
  push  si
  jmp   @primeiro_char
@imprime:
  call  imprime_char
  inc   si          {aponta para o proximo caracter}
@primeiro_char:
  mov   al,[si]
  cmp   al,0        {string acabou?}
  jne   @imprime    {se nao, imprime o caracter}
  pop   si
  pop   ax
end;


{Esta rotina le um caracter do teclado, e nao imprime na tela.
 Nao aceita codigos extendidos. Caracter em AL}
function le_tecla : char; assembler;
asm
  mov   ah,$8
@inicio:
  int   $21
  cmp   al,0
  jne   @fim
  int   $21
  jmp   @inicio
@fim:
end;

{Esta rotina le um inteiro de ate 3 digitos decimais
 O numero fica em AL. Se o usuário pressionar <enter> sem 
ter digitado nada, a funcao retorna 0}
function le_inteiro : byte; assembler;
asm
  push  dx
  push  cx
  push  bx
  mov   cx,3        {cx=caracteres restantes}
  mov   bx,0        {bx vai guardar o valor temporario}
  mov   dl,10
@inicio:
  call  le_tecla
  cmp   al,13       {teclou <enter>?}
  je    @finalizar  {se sim, salta}
  cmp   al,$30
  jb    @inicio     {se ASCII < $30, caracter invalido}
  cmp   al,$39
  ja    @inicio     {se ASCII > $39, caracter invalido}
  call  imprime_char    {imprimir!, digitaram algo q presta}
  xchg  ax,bx
  mul   dl          {multiplica o valor antigo por 10}
  xchg  ax,bx
  sub   al,$30      {converte ASCII para decimal}
  add   bl,al
  dec   cx
  jnz   @inicio     {se cx <> 0, pode digitar mais}
  jmp   @fim
@finalizar:
  cmp   cx,3        {usuario digitou algo valido?}
  jne   @fim        {sim, foi digitado algo}
  mov   al,$30
  call  imprime_char
@fim:
  mov   al,bl
  pop   bx
  pop   cx
  pop   dx
  call  salta_linha
end;