Me Ajudem! Historico do MSN

boss-sp · 01-04-2005, 17:02

Eu formatei minha maquina mas guardei o historico do msn. esta no formato .xml...
Qdo tento abrir com o Internet Explorer, ou mesmo com o meu msn atual, nao consigo. o Internet Explorer da a seguinte mensagem:
A página XML não pode ser exibida
Não é possível exibir a entrada XML usando a folha de estilos . Corrija o erro e clique no botão Atualizar ou tente novamente mais tarde.

--------------------------------------------------------------------------------

Inválido no nível superior do documento. Erro ao processar o recurso 'file:///C:/Documents and Settings/microxp/Meus docume...

Gente... que programa posso usar pra ver o historico????
Muito obrigado!!!

Eric Gagulich · 01-04-2005, 17:08

Provavelmente deve estar faltando criar o arquivo MessageLog.xsl (XSL Stylesheet) na pasta onde foi salvo o histórico das mensagens:

1. Execute o Bloco de notas (Iniciar > Executar > digite: notepad.exe);

2. Copie & cole o texto abaixo indicado:

Código:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<!-- localized strings -->
<xsl:variable name='ColumnHeader_Date'>Data</xsl:variable>
<xsl:variable name='ColumnHeader_Time'>Hora</xsl:variable>
<xsl:variable name='ColumnHeader_From'>De</xsl:variable>
<xsl:variable name='ColumnHeader_To'>Para</xsl:variable>
<xsl:variable name='ColumnHeader_Message'>Mensagem</xsl:variable>

<!-- variables -->
<xsl:variable name='Debug'>0</xsl:variable>

<xsl:variable name='TableStyle'>font-family:Verdana; font-size:67%; text-align:left; vertical-align:top; table-layout:fixed</xsl:variable>
<xsl:variable name='GutterStyle'>width:2ex</xsl:variable>
<xsl:variable name='HeaderStyle'>border-bottom:1 solid black</xsl:variable>

<xsl:variable name='UseZebraStripe'>1</xsl:variable>
<xsl:variable name='ZebraStripeStyle'>background-color:#e0edff</xsl:variable>

<xsl:variable name='MostRecentSessionFirst'>0</xsl:variable>


<xsl:template match="Log">

    <html dir='ltr'>
    <head>
        <title>
            Message Log for <xsl:value-of select="@LogonName"/>
            <xsl:if test="$Debug = 1"> (Debug)</xsl:if>
        </title>

        <xsl:if test="$Debug = 1">
            <span style="font-family:trebuchet ms; font-size:120%">
                Debug Version
            </span>
            <hr/>
        </xsl:if>
    </head>

    <body style='margin:0'>

        <table id='BodyTable' style="{$TableStyle}" cellspacing='0'>

            <xsl:if test="$Debug = 1">
                <col style="vertical-align:top; width:5ex;"/>
                <col style='{$GutterStyle}' />
            </xsl:if>

            <col style="width:16ex;"/>
            <col style='{$GutterStyle}' />
            <col style="width:16ex;"/>
            <col style='{$GutterStyle}' />
            <col style="width:21ex;"/>
            <col style='{$GutterStyle}' />
            <col style="width:21ex;"/>
            <col style='{$GutterStyle}' />
            <col style="width:70ex;"/>

            <thead>
                <tr>
                    <xsl:if test="$Debug = 1">
                        <th style="{$HeaderStyle}">SID</th>
                        <th/>
                    </xsl:if>
                    <th style="{$HeaderStyle}">
                        <xsl:value-of select="$ColumnHeader_Date"/>
                    </th>
                    <th/>
                    <th style="{$HeaderStyle}">
                        <xsl:value-of select="$ColumnHeader_Time"/>
                    </th>
                    <th/>
                    <th style="{$HeaderStyle}">
                        <xsl:value-of select="$ColumnHeader_From"/>
                    </th>
                    <th/>
                    <th style="{$HeaderStyle}">
                        <xsl:value-of select="$ColumnHeader_To"/>
                    </th>
                    <th/>
                    <th style="{$HeaderStyle}">
                        <xsl:value-of select="$ColumnHeader_Message"/>
                    </th>
                </tr>
            </thead>

            <tbody style='vertical-align:top'>
                <xsl:choose>

                    <!-- newest session first -->
                    <xsl:when test="$MostRecentSessionFirst = 1">
                        <xsl:apply-templates>
                            <xsl:sort select='@SessionID' order='descending' data-type='number'/>
                            <xsl:sort select='@DateTime'  order='ascending'/>
                        </xsl:apply-templates>
                    </xsl:when>

                    <!-- oldest session first -->
                    <xsl:otherwise>
                        <xsl:apply-templates>
                            <xsl:sort select='@SessionID' order='ascending' data-type='number'/>
                            <xsl:sort select='@DateTime'  order='ascending'/>
                        </xsl:apply-templates>
                    </xsl:otherwise>

                </xsl:choose>
            </tbody>
        </table>
    </body>
    </html>

</xsl:template>


<xsl:template match="Message">
    <tr>
        <xsl:call-template name="CommonMessageProcessing" />

        <td> <xsl:apply-templates select="From/User"/> </td>
        <td/>
        <td> <xsl:apply-templates select="To/User"/> </td>
        <td/>
        <td>
            <span>
                <xsl:attribute name="style">
                    <xsl:value-of select="Text/@Style"/>
                </xsl:attribute>
                <xsl:value-of select="Text"/>
            </span>
        </td>
    </tr>
</xsl:template>


<xsl:template match="Invitation|InvitationResponse|Join|Leave">
    <tr>
        <xsl:call-template name="CommonMessageProcessing" />

        <td/>  <!-- From -->
        <td/>
        <td/>  <!-- To -->
        <td/>
        <td>
            <span>
                <xsl:attribute name="style">
                    <xsl:value-of select="Text/@Style"/>
                </xsl:attribute>
                <xsl:value-of select="Text"/>
            </span>
        </td>
    </tr>
</xsl:template>


<xsl:template match="User">
    <!-- add a comma before all but the first user -->
    <xsl:if test="position() != 1">, </xsl:if>

    <xsl:value-of select="@FriendlyName"/>
</xsl:template>


<xsl:template name="CommonMessageProcessing">
    <!-- zebra-stripe the sessions -->
    <xsl:if test="$UseZebraStripe = 1">
        <xsl:if test="(@SessionID mod 2) = 1">
            <xsl:attribute name="style">
                <xsl:value-of select="$ZebraStripeStyle"/>
            </xsl:attribute>
        </xsl:if>
    </xsl:if>

    <xsl:if test="$Debug = 1">
        <td> <xsl:value-of select="@SessionID"/> </td>
        <td/>
    </xsl:if>

    <td> <xsl:value-of select="@Date"/> </td>
    <td/>
    <td> <xsl:value-of select="@Time"/> </td>
    <td/>
</xsl:template>


</xsl:stylesheet>

3. Em seguida salve este arquivo com o nome: MessageLog.xsl dentro da pasta onde foi salvo o histórico das suas mensagens.

boss-sp · 05-04-2005, 14:26

Cara.. valeu mesmo.... mas ainda assim nao da pra vizualizar.... deve ser pq o meu msn mudou.... ele continua dando o mesmo erro.... mas agradeço muito pela força!!!

Eric Gagulich · 05-04-2005, 20:10

Estranho, aqui pelo menos funcionou 100%. Qual versão do MSN Messenger você está usando!? Você copiou o arquivo MessageLog.xsl na mesma pasta onde foram salvos os históricos!?

boss-sp · 08-04-2005, 21:09

cara... eu fiz sim.. to com a versao mais nova q tem....

01-04-2005, 17:02	#1 (permalink)
boss-sp Novo Membro Registrado em: Apr 2005 Idade: 37 Mensagens: 89 Reputação: 15	Me Ajudem! Historico do MSN Eu formatei minha maquina mas guardei o historico do msn. esta no formato .xml... Qdo tento abrir com o Internet Explorer, ou mesmo com o meu msn atual, nao consigo. o Internet Explorer da a seguinte mensagem: A página XML não pode ser exibida Não é possível exibir a entrada XML usando a folha de estilos . Corrija o erro e clique no botão Atualizar ou tente novamente mais tarde. -------------------------------------------------------------------------------- Inválido no nível superior do documento. Erro ao processar o recurso 'file:///C:/Documents and Settings/microxp/Meus docume... Gente... que programa posso usar pra ver o historico???? Muito obrigado!!!

05-04-2005, 20:10	#4 (permalink)
Eric Gagulich Highlander Registrado em: Aug 2002 Mensagens: 12.628 Reputação: 139	Estranho, aqui pelo menos funcionou 100%. Qual versão do MSN Messenger você está usando!? Você copiou o arquivo MessageLog.xsl na mesma pasta onde foram salvos os históricos!? __________________ Antes de enviar Mensagem Privada, leia isto aqui: Eu não respondo questões técnicas por MP. Portanto, não perca o seu tempo...

		FórumGdH > Software, Segurança e Mac (Apple) > Windows
Me Ajudem! Historico do MSN

1. Limpar documentos e histórico do IE estão travando (Resolvido) 2. Opera, histórico e guias???
Mais resultados? Use nossa pesquisa.

05-04-2005, 14:26	#3 (permalink)
boss-sp Novo Membro Registrado em: Apr 2005 Idade: 37 Mensagens: 89 Reputação: 15	Cara.. valeu mesmo.... mas ainda assim nao da pra vizualizar.... deve ser pq o meu msn mudou.... ele continua dando o mesmo erro.... mas agradeço muito pela força!!!

08-04-2005, 21:09	#5 (permalink)
boss-sp Novo Membro Registrado em: Apr 2005 Idade: 37 Mensagens: 89 Reputação: 15	cara... eu fiz sim.. to com a versao mais nova q tem....

Opções do Tópico
Exibir Versão para Impressão Envie essa página por e-mail